Add coveralls support, maybe.

build.gradle

@@ -4,6 +4,8 @@ subprojects {
     apply plugin: 'findbugs'
     apply plugin: 'pmd'
 
+    apply from: '../gradle/coverage.gradle'
+
     configurations {
         bundle
 
@@ -140,6 +142,7 @@ buildscript {
 
     dependencies {
         classpath group: 'com.dmdirc', name: 'git-version', version: '1.0'
+        classpath 'org.kt3k.gradle.plugin:coveralls-gradle-plugin:2.1.0'
     }
 }
 
@@ -163,3 +166,6 @@ def plugin(name) {
         println "Couldn't find project $name"
     }
 }
+
+apply from: 'gradle/coveralls.gradle'
+

circle.yml

@@ -40,6 +40,10 @@ test:
     - ./gradlew --stacktrace --parallel plugins:jar plugins:test:
         pwd:
           ../meta
+  post:
+    - ./gradlew plugins:coveralls:
+        pwd:
+          ../meta
 
 general:
   artifacts:

gradle/coverage.gradle

@@ -0,0 +1,12 @@
+apply plugin: 'jacoco'
+
+jacocoTestReport {
+  group = 'Coverage reports'
+  description = 'Generates a test coverage report for a project'
+
+  reports {
+    xml.enabled = true
+    html.enabled = true
+  }
+}
+

gradle/coveralls.gradle

@@ -0,0 +1,38 @@
+apply plugin: 'com.github.kt3k.coveralls'
+apply plugin: 'jacoco'
+
+repositories {
+  jcenter()
+}
+
+task jacocoRootReport(type: JacocoReport, group: 'Coverage reports', dependsOn: subprojects.test) {
+  description = 'Generates an aggregate report from all subprojects'
+
+  additionalSourceDirs = files(subprojects.sourceSets.main.allSource.srcDirs)
+  sourceDirectories = files(subprojects.sourceSets.main.allSource.srcDirs)
+  classDirectories = files(subprojects.sourceSets.main.output)
+  executionData = files(subprojects.jacocoTestReport.executionData)
+
+  reports {
+    html.enabled = true
+    xml.enabled = true
+  }
+
+  doFirst {
+    executionData = files(executionData.findAll { it.exists() })
+  }
+}
+
+coveralls {
+  jacocoReportPath = "${buildDir}/reports/jacoco/jacocoRootReport/jacocoRootReport.xml"
+  subprojects.sourceSets.main.allSource.srcDirs*.path.each { sourceDirs.addAll(it) }
+}
+
+tasks.coveralls {
+  group = 'Coverage reports'
+  description = 'Uploads the aggregated coverage report to Coveralls'
+
+  dependsOn jacocoRootReport
+  onlyIf { System.env.'CI' }
+}
+