DMDirc-Client/build.gradle

plugins {
  id 'com.dmdirc.git-version' version '1.0'
  id 'com.github.kt3k.coveralls' version '2.6.3'
  id 'maven-publish'
  id 'java'
  id 'findbugs'
  id 'pmd'
  id 'idea'
}

group = 'com.dmdirc'

idea {
    module {
         sourceDirs += file('src/main/generated')
         testSourceDirs += file('src/test/generated_tests')
         generatedSourceDirs = [file('src/main/generated'), file('src/test/generated_tests')]
    }
}

configurations {
    bundle

    compile {
        extendsFrom bundle
    }
}

configurations.all {
    resolutionStrategy.cacheDynamicVersionsFor 2, 'minutes'
    resolutionStrategy.cacheChangingModulesFor 2, 'minutes'
}

dependencies {
    compile group: 'com.google.code.findbugs', name: 'jsr305', version: '3.0.1'
    compile group: 'com.squareup.dagger', name: 'dagger-compiler', version: '1.2.5'
    compile group: 'com.google.auto.value', name: 'auto-value', version: '1.3'
    compile group: 'org.osgi', name: 'org.osgi.core', version: '6.0.0'

    bundle group: 'ch.qos.logback', name: 'logback-classic', version: '1.1.7'
    bundle group: 'org.slf4j', name: 'slf4j-api', version:'1.7.21'
    bundle group: 'com.squareup.dagger', name: 'dagger', version: '1.2.5'
    bundle group: 'com.esotericsoftware.yamlbeans', name: 'yamlbeans', version: '1.09'
    bundle group: 'com.getsentry.raven', name: 'raven', version: '7.8.0'
    bundle group: 'com.google.guava', name:'guava', version: '19.0'
    bundle group: 'net.engio', name: 'mbassador', version: '1.3.0'
    bundle group: 'com.google.code.gson', name: 'gson', 'version': '2.5'

    bundle group: 'com.dmdirc', name: 'com.dmdirc.events.eventbus', version: '+', changing: true
    bundle group: 'com.dmdirc', name: 'com.dmdirc.util.io.yaml', version: '+', changing: true

    bundle group: 'com.dmdirc', name: 'api', version: '+', changing: true
    bundle group: 'com.dmdirc', name: 'util', version: '+', changing: true
    bundle group: 'com.dmdirc', name: 'parser-common', version: '+', changing: true

    testCompile group: 'junit', name: 'junit', version: '4.12'
    testCompile group: 'org.mockito', name: 'mockito-core', version: '2.2.7'
    testCompile group: 'com.google.jimfs', name: 'jimfs', version: '1.1'
}

sourceCompatibility = 1.8
targetCompatibility = 1.8

repositories {
    mavenCentral()
    maven { url 'https://artifactory.dmdirc.com/artifactory/repo' }
    maven { url 'https://oss.sonatype.org/content/repositories/snapshots' }
}

apply from: 'gradle/analysis.gradle'
apply from: 'gradle/publishing.gradle'
apply from: 'gradle/jar.gradle'
apply from: 'gradle/fatjar.gradle'

task wrapper(type: Wrapper) {
    gradleVersion = '3.1'
}